;===============================================================================
;  SD2200系列EEPROM功能测试程序
;     VER1。00
;
;       注: 单片机是AT89C51，外晶振为12Mhz,在兴威帆公司的SD7218评估板上运行
;       Last update:2006/04/29
;       本程序仅供参考，如有问题请联系：陈工 0755-83246178,fax:83225561
;       13922865036   chendw@whwave.com.cn  http://www.whwave.com.cn
;===============================================================================
;define the general register
;LED寄存器
        DIG1    EQU     20H             ;LED第一位缓冲器
        DIG2    EQU     21H             ;
        DIG3    EQU     22H             ;
        DIG4    EQU     23H             ;
        DIG5    EQU     24H             ;
        DIG6    EQU     25H             ;
        DIG7    EQU     26H             ;
        DIG8    EQU     27H
        FLAG    EQU     28H             ;通用标志寄存器
                                        ;BIT0=1, ACK ERR
                                        ;BIT0=0 ,ACK OK

        YEAR    EQU     30H             ;年
        MONTH   EQU     31H             ;月
        DAY     EQU     32H             ;日
        WEEK    EQU     33H             ;星期
        HOUR    EQU     34H             ;小时
        MINUTE  EQU     35H             ;分钟
        SECOND  EQU     36H             ;秒
;单片机与实时时钟间通信寄存器
        TIMETEMP        EQU     2EH     ;时间数据缓存器
        TIMETX          EQU     43H     ;时间数据发送寄存器
        TIMERX          EQU     44H     ;时间数据接收寄存器
;单片机与IIC通信寄存器
        IICTEMP         EQU     2FH     ;IIC标志寄存器
        SLAVE_ADD       EQU     40H     ;SD7218地址寄存器
        DATAI1          EQU     41H
        DATAI2          EQU     42H
        TXBUF           EQU     47H     ;IIC数据发送寄存器
        RXBUF           EQU     48H     ;IIC数据接收寄存器
        KEYBUF          EQU     49H     ;键盘数据缓冲器
        READDATA        EQU     4FH
;温度数据寄存器
        TEMPHI 		EQU     50H     ;温度高字节
        TEMPLO  	EQU     51H     ;温度低字节
;SRAM寄存器
        SRAMADD_LO	EQU     52H     ;SRAM地址低8位
        SRAMADD_HI	EQU     53H     ;SRAM地址高8位
        SRAMDATA        EQU     54H     ;写入SRAM内的数据
        TEMP            EQU     5CH     ;
;---------------------------------------------------------------------------
;define port bit
;各通信口位代号
        SDA     EQU     P3.1            ;IIC的SDA口线
        SCL     EQU     P3.2            ;IIC的SCL口线
        KEY     EQU     P3.0            ;键盘中断信号线
        T_SDA   EQU     P3.4            ;SD2200的SDA口线
        T_SCL   EQU     P3.5            ;SD2200的SCL口线

;===========================================================================

        ORG     0000H                   ;RESET
        LJMP    START

;---------------------------------------------------------------------------

        ORG     0100H
START:
        CLR     A                       ;开始初始化各寄存器
        MOV     IE,A                    ;关中断
        MOV     SP,#60H                 ;定义堆栈
        CLR     FLAG                    ;清除标志位
	LCALL	LONGDELAY
	LCALL	LONGDELAY
	LCALL	TIME_RESET		;RTC复位
	LCALL   TIMESTATUS_INT12ON      ;设置小时制式及中断输出
	
	MOV     YEAR,#06H
	MOV     MONTH,#05H
	MOV     DAY,#05H
	MOV     WEEK,#0H
	MOV     HOUR,#0H
	MOV     MINUTE,#0H
	MOV     SECOND,#0H
	LCALL   WRITE_TIME		;写时间

LOOP:
        LCALL   READ_TIME		;读时间
        NOP
        MOV     SRAMADD_HI,#0
        MOV     SRAMADD_LO,#0
        MOV     SRAMDATA,#058H		;测试用的随机数
	LCALL	WRITESRAM
	MOV     SRAMDATA,#0		;清SRAMDATA
	LCALL   READSRAM
	NOP
	JMP	LOOP




;==================读实时时钟实时数据寄存器子程序==========================
;功能：从实时时钟读入当前时间数据                                         |
;入口：NONE                                                               |
;出口：接收数据放在年、月、日、星期、时、分、秒各寄存器                   |
;影响资源：A，R0,R3,TIMETX,TIMERX,YEAR,MONTH,DAY,WEEK,HOUR,MINUTE,SECOND  |
;==========================================================================
READ_TIME:
RDTIME_LOOP:
	LCALL	T_IICSTART
        JB      FLAG.1,T_ERR_IICSTOP      ;如SDA线被箝位为低电平则退出
	MOV	TIMETX,#65H               ;发送读时钟数据命令
	LCALL	T_SENDH_L
        JB      FLAG.0,T_ERR_IICSTOP      ;ACK信号不正常则退出.
	MOV	R0,#YEAR
	MOV	R3,#07H
T_RDTIME1:
	LCALL	T_RXL_H
	MOV	A,TIMERX
	MOV	@R0,A
	INC	R0
 	DJNZ	R3,RDTIME2              ;读完一个字节数据后确认数据传输
        JMP     RDTIME3                 ;若为最后一个字节数据则为NOACK
RDTIME2:
        CALL    T_ACK
        JMP     T_RDTIME1
RDTIME3:
        CALL    T_NOACK
        LCALL   T_IICSTOP
        ANL     HOUR,#03FH              ;小时的高两位在24小时制时没有用,如果是12小时制请删掉此行.
RDTIME_RET:
        RET

T_ERR_IICSTOP:
        LCALL   T_IICSTOP
        RET

;==================写实时时钟实时数据寄存器子程序==========================
;功能：向时间寄存器写入时间数据                                           |
;入口：NONE                                                               |
;出口：时间数据放在年、月、日、星期、时、分、秒各寄存器                   |
;影响资源：A，R0,R3,TIMETX,TIMERX,YEAR,MONTH,DAY,WEEK,HOUR,MINUTE,SECOND  |
;==========================================================================
WRITE_TIME:
	LCALL	T_IICSTART
        JB      FLAG.1,T_ERR_IICSTOP     ;如SDA线被箝位为低电平则退出
	MOV	TIMETX,#64H              ;发送写时钟数据命令
	LCALL	T_SENDH_L
        JB      FLAG.0,T_ERR_IICSTOP     ;ACK信号不正常则退出.
	MOV	R0,#YEAR
	MOV	R3,#07H
T_WRTIME1:
	MOV     A,@R0
	MOV     TIMETX,A
	LCALL	T_SENDL_H
	INC	R0
 	DJNZ	R3,T_WRTIME1             ;写完了吗?
        LCALL   T_IICSTOP
        RET


;============================写状态寄存器程序==============================
;功能：读/写实时时钟状态寄存器，对其进行设置                              |
;入口：NONE           出口：NONE                                          |
;影响资源： A，TIMETX                                                     |
;==========================================================================
TIMESTATUS_INT12ON:
        LCALL   T_IICSTART
        JNB     FLAG.1,TIME_SETMODE_1
        LJMP    T_ERR_IICSTOP           ;SDA线被箝位为低电平则退出
TIME_SETMODE_1:
	MOV	TIMETX,#60H             ;发送写时钟状态寄存器_1命令
	LCALL	T_SENDH_L
        JNB     FLAG.0,TIME_SETMODE_2
        LJMP    T_ERR_IICSTOP           ;ACK信号不正常则退出?
TIME_SETMODE_2:
	MOV	TIMETX,#32H             ;24小时进制,/INT1及/INT2脚的输出
	LCALL	T_SENDL_H		;
        LCALL   T_IICSTOP                 ;

        LCALL   T_IICSTART
	MOV	TIMETX,#62H             ;发送写时钟状态寄存器_2命令
	LCALL	T_SENDH_L
	MOV	TIMETX,#18H             ;/INT1为32768hz,/INT2脚输出固定频率
	LCALL	T_SENDL_H	        ;
        LCALL   T_IICSTOP               ;

        LCALL   T_IICSTART
	MOV	TIMETX,#6AH             ;发送写INT1_2命令
	LCALL	T_SENDH_L
	MOV	TIMETX,#10H             ;/INT2输出 16HZ
	LCALL	T_SENDL_H	        ;
        LCALL   T_IICSTOP               ;
        RET

;-----------------------------------
TIMESTATUS_INT12OFF:
        LCALL   T_IICSTART
	MOV	TIMETX,#62H             ;发送写时钟状态寄存器_2命令
	LCALL	T_SENDH_L
	MOV	TIMETX,#00H             ;关闭/INT1和/INT2脚的输出
	LCALL	T_SENDL_H	        ;
        LCALL   T_IICSTOP

        RET

;============================写状态寄存器程序==============================
;功能：读/写实时时钟状态寄存器，对其进行设置                              |
;入口：NONE           出口：NONE                                          |
;影响资源： A，TIMETX                                                     |
;==========================================================================
TIME_RESET:
        LCALL   T_IICSTART
        JNB     FLAG.1,TIME_RESET_1
        LJMP    T_ERR_IICSTOP           ;SDA线被箝位为低电平则退出
TIME_RESET_1:
        MOV     TIMETX,#60H		;读写状态寄存器_1命令
        LCALL   T_SENDH_L
        MOV     TIMETX,#03H		;RESET命令,24H制
        LCALL   T_SENDL_H
        LCALL   T_IICSTOP
        RET
;----------------------------------------------------


;==============================WRITE SRAM/EEPROM ==========================
;功能:把数据储存到SD2200的SRAM/EEPROM地址中去
;入口:储存地址在SRAMADD_HI和SRAMADD_LO中,数据在SRAMDATA中
;出口:无
;影响资源:A,TIMETX
;==========================================================================
WRITESRAM:
        LCALL    T_IICSTART
        JNB      FLAG.1,SRAM_WRITE_1
        LJMP     SRAM_ERROR                    ;SDA线被箝位为低电平则退出
SRAM_WRITE_1:
        MOV      TIMETX,#0A0H		       ;A2A1A0="000"
        LCALL    T_SENDH_L		       ;SLAVE ADDRESS
        JNB      FLAG.0,SRAM_WRITE_2
        LJMP     SRAM_ERROR                    ;ACK信号不正常则退出?
SRAM_WRITE_2:
	MOV      A,SRAMADD_LO		       ;RAM地址低8位为SRAMADD_LO
        MOV      TIMETX,A      		       ;WORD ADDRESS_LO_8
        LCALL    T_SENDH_L

        MOV	 A,SRAMDATA		       ;要写入的数据在SRAMDATA	
	MOV	 TIMETX,A
	LCALL	 T_SENDH_L
	LCALL	 T_IICSTOP
        LCALL    DELAY10MS		       ;对EEPROM要延时10ms,SRAM不用延时10ms
        RET

;==========================读取SRAM/EEPROM 数据子程序=======================
;功能:从SRAM中读取数据
;入口:SRAM读取数据地址在SRAMADD_HI.SRAMADD_LO中,数据在SRAMDATA中
;出口:读取数据储存在CPU中
;影响资源:A,TIMETX
;===========================================================================
READSRAM:
        LCALL    T_IICSTART
        JNB      FLAG.1,SRAM_READ_1
        LJMP     SRAM_ERROR                  ;SDA线被箝位为低电平则退出
SRAM_READ_1:
        MOV      TIMETX,#0A0H		     ;A2A1A0="000"
        LCALL    T_SENDH_L		     ;SLAVE ADDRESS
        JNB      FLAG.0,SRAM_READ_2
        LJMP     SRAM_ERROR                  ;ACK信号不正常则退出?
SRAM_READ_2:
 
        MOV      A,SRAMADD_LO                ;RAM地址的低八位
        MOV      TIMETX,A      	             ;WORD ADDRESS_LO_8
        LCALL    T_SENDH_L

        LCALL    T_IICSTART
        MOV      A,#0A1H               	     ;发送读操作指令
        MOV      TIMETX,A
        LCALL    T_SENDH_L

        LCALL    T_RXH_L
        MOV      A,TIMERX
        MOV      SRAMDATA,A
        
READSRAM_INT:
        CALL     T_NOACK
        LCALL    T_IICSTOP
        RET
        
        
SRAM_ERROR:
        SETB     FLAG.7
        JMP      READSRAM_INT
;============================短延时子程序==================================
;功能：延时         入口：NONE             出口：NONE                     |
;影响资源：R7,PSW                                                         |
;==========================================================================
DELAY:	MOV	R7,#2
DELAY1:	NOP
	DJNZ	R7,DELAY1
	RET
;--------
DELAY_7218:
	MOV	R7,#15
DELAY1_7218:
	NOP
	DJNZ	R7,DELAY1_7218
	RET

LONGDELAY:                     ;DELAY 300MS
        MOV     R6,#240
LD0:    MOV     R7,#250        ;5*250*240
LD1:    NOP
        NOP
        NOP
        DJNZ    R7,LD1
        DJNZ    R6,LD0
        RET

DELAY10MS:                     ;DELAY >10MS
        MOV     R6,#11
LD00:    MOV     R7,#250        ;5*250*11
LD10:    NOP
        NOP
        NOP
        DJNZ    R7,LD10
        DJNZ    R6,LD00
        RET
;============================ACK===========================================
;功能：延时         入口：NONE             出口：NONE                     |
;影响资源：                                                               |
;==========================================================================
T_ACK:  CLR      TIMETEMP.1
        LCALL    T_BITOUT
        RET

;============================ACK===========================================
;功能：延时         入口：NONE             出口：NONE                     |
;影响资源：                                                               |
;==========================================================================
T_NOACK:  SETB     TIMETEMP.1
        LCALL    T_BITOUT
        RET
;===============================保存错误代码===============================
;功能：保存MCU与IIC接口通信时的错误状态                                   |
;入口：TIMETEMP.0=ACK位缙?                                               |
;出口：FLAG.0 =错误代码                                                   |
;==========================================================================
T_ACK_ERR:
        JNB     TIMETEMP.0,T_ACK_ERR_RET  ;检查ACK信号是否正常
        SETB    FLAG.0                  ;置ACK出错标志位
T_ACK_ERR_RET:
        RET
;===============================启用IIC总线================================
;功能：开启实时时钟的IIC总线
;入口：NONE       出口：NONE
;影响资源：NONE
;==========================================================================
T_IICSTART:
        CLR     FLAG.1
	SETB	T_SDA
	SETB	T_SCL
	LCALL	DELAY
        JB      T_SDA,T_IIC_SDAHI
        SETB    FLAG.1
T_IIC_SDAHI:
	CLR	T_SDA
        LCALL   DELAY
	CLR	T_SCL
        LCALL    DELAY
        RET
;===============================关闭IIC总线================================
;功能：关闭实时时钟IIC总线
;入口：NONE       出口：NONE
;影响资源：NONE
;==========================================================================
T_IICSTOP:CLR	T_SDA
	SETB	T_SCL
	LCALL	DELAY
	SETB	T_SDA
	LCALL	DELAY
	RET

;============================发送一个字节，由高位到低位发送================
;功能：从MCU发送一个字节给实时时钟,由高位到低位发送                        |
;入口：发送数据放在TIMETX          出口：NONE                              |
;影响资源：A，R2，TIMETX                                                   |
;==========================================================================
T_SENDH_L:MOV	A,TIMETX
	MOV	R2,#08H
        CLR     FLAG.0
T_SENDH_L1:
        MOV	C,ACC.7
        MOV	TIMETEMP.1,C
	LCALL	T_BITOUT
	RL	A
	DJNZ	R2,T_SENDH_L1
        LCALL   T_BITIN
        LCALL   T_ACK_ERR
        RET
;==========================发送一个字节，由低位到高位发送==================
;功能：从MCU发送一个字节给实时时钟,由低位到高位发送                        |
;入口：发送数据放在TIMETX          出口：NONE                              |
;影响资源：A，R2，TIMETX                                                   |
;==========================================================================
T_SENDL_H:MOV	A,TIMETX
	MOV	R2,#08H
        CLR     FLAG.0
T_SENDL_H1:
        MOV	C,ACC.0
        MOV	TIMETEMP.1,C
        LCALL	T_BITOUT
	RR	A
	DJNZ	R2,T_SENDL_H1
        LCALL   T_BITIN
        LCALL   T_ACK_ERR
	RET
;=================================接收一个字节=============================
;功能：MCU从IIC总线接收一个字节,MSB在前,LSB在后                           |
;入口：NONE          出口：接收数据放在RXBUF中                            |
;影响资源：A，R2，TIMEBIT，RXBUF                                          |
;==========================================================================
T_RXH_L:MOV	R2,#08H
T_RXH_L1: LCALL	T_BITIN
        MOV	C,TIMETEMP.0
        MOV	ACC.7,C
	RLC	A
	DJNZ	R2,T_RXH_L1
        MOV     TIMERX,A
        RET
;=================================接收一个字节=============================
;功能：MCU从IIC总线接收一个字节,LSB在前,MSB在后                           |
;入口：NONE          出口：接收数据放在RXBUF中                            |
;影响资源：A，R2，TIMEBIT，RXBUF                                          |
;==========================================================================
T_RXL_H:MOV	R2,#08H
T_RXL_H1: LCALL	T_BITIN
        MOV	C,TIMETEMP.0
	RRC	A
	DJNZ	R2,T_RXL_H1
        MOV     TIMERX,A
        RET
;================================送出一位数================================
;功能：从MCU发送一位数给实时时钟                                          |
;入口：发送位数放在EEPREM.1       出口：NONE                              |
;影响资源：A，TIMETEMP                                                    |
;==========================================================================
T_BITOUT:
        MOV	C,TIMETEMP.1
	MOV	T_SDA,C
	LCALL	DELAY
	SETB	T_SCL
	LCALL	DELAY
	CLR	T_SCL
        LCALL   DELAY
	RET
;=================================读入一位数===============================
;功能：MCU从实时时钟接收一位数                                            |
;入口：NONE       出口：接收位数放在TIMETEMP.0                            |
;影响资源：A，TIMETEMP                                                    |
;==========================================================================
T_BITIN:
        SETB	T_SDA
        SETB    T_SCL
	LCALL	DELAY
	MOV	C,T_SDA
        MOV	TIMETEMP.0,C
	CLR	T_SCL
        CLR     T_SDA
        LCALL   DELAY
	RET

        END